Excel 以行列为条件的二维表查询 公式锦集
诠释标题：意即查询Excel第X行第Y列的值，X、Y的值按条件定位。
看实例（文末附实例下载）
| A | B | C | D | |
| 1 | 域名 | baidu | yahoo | |
| 2 | surda.cn | 225 | 778 | 3000 |
| 3 | t.surda.cn | 200 | 600 | 1000 |
| 4 | b.surda.cn | 195 | 550 | 700 |
| 5 | img.surda.cn | 600 | 700 | 800 |
Example 1 : 查询域名surda.cn在baidu的访问量 （肉眼一看答案是225 ~_^,这里不需要用肉眼。）
| F | G | H |
| 域名 | 来源 | 公式1 |
| surda.cn | baidu | 225 |
公式1=INDEX(A1:D5,MATCH(F2,A1:A5,),MATCH(G2,A1:D1,))
函数INDEX(区域，行，列)最切题了，返回表格或数组中的元素值，此元素由行号和列号的索引值给定。
看标题，我说的是公式锦集，那自然不只介绍这一例公式了，接着往下看……
| F | G | H | I | J | K | L | M | N |
| 域名 | 来源 | 公式1 | 公式2 | 公式3 | 公式4 | 公式5 | 公式6-1 | 公式6-2 |
| surda.cn | baidu | 225 | 225 | 225 | 225 | 225 | 225 | 225 |
| 公式7-1 | 公式7-2 | 公式8-1 | 公式8-2 | 公式9-1 | 公式9-2 | 公式10 | ||
| 225 | 225 | 225 | 225 | 225 | 225 | 225 |
surda共计写了14个公式来实现，分别用到了index,offset,sumproduct,sum,indirect,sumif,lookup,vlookup等Excel函数，公式分别如下：
公式2=OFFSET(A1,MATCH(F2,A2:A5,),MATCH(G2,B1:D1,))
公式3=SUMPRODUCT((B1:D1=G2)*(A2:A5=F2)*B2:D5)
公式4=SUM((B1:D1=G2)*(A2:A5=F2)*B2:D5) 数组公式
公式5=INDIRECT("r"&MATCH(F2,A1:A5,)&"c"&MATCH(G2,A1:D1,),)
公式6-1=SUMIF(A1:D1,G2,OFFSET(A1:D1,MATCH(F2,A2:A5,),,))
公式6-2=SUMIF(A1:A5,F2,OFFSET(A1:A5,,MATCH(G2,B1:D1,),))
公式7-1=INDEX(B2:D5,LOOKUP(F2,A2:A5,{1;2;3;4}),LOOKUP(G2,B1:D1,{1,2,3,4}))
公式7-2=INDEX(B2:D5,LOOKUP(1,0/(A2:A5=F2),{1;2;3;4}),LOOKUP(1,0/(B1:D1=G2),{1,2,3,4}))
公式8-1=SUMPRODUCT((A2:A5&B1:D1=F2&G2)*B2:D5)
公式8-2=SUM((A2:A5&B1:D1=F2&G2)*B2:D5) 数组公式
公式9-1=LOOKUP(F2,A2:A5,OFFSET(A2:A5,,MATCH(G2,B1:D1,)))
公式9-2=LOOKUP(1,0/(A2:A5=F2),OFFSET(A2:A5,,MATCH(G2,B1:D1,)))
公式10=VLOOKUP(F2,A2:D5,MATCH(G2,A1:D1,),)
对公式就不多做解释，需要的盆友下载实例去研究吧。
EXCEL貌似功能很强大啊，对excel宏蛮有兴趣
Excel的确很强大。宏属编程的范畴、高阶应用了。欢迎常来！
还真没有研究过呢
呵呵，工作使然，我需要经常接触Excel。分享的同时，其实也是在巩固。欢迎常来！
wobu.ws=“我不猥琐”
good